TM1 Forum

Code: Select all

' VB Script Code
' Fix for the August Microsoft Office patch that
' seems to have de-registered or corrupted the registry
' entries for various TM1 and Office controls
' Created 17.08.2012, Tony Murphy

option explicit

' Two common folders for TM1
' For us people either installed using the full CD or more commonly a cut down installer that I created
' Assuming they installed in the default folders there should only be two places for the TM1 files (any more and this won't work)
const tm1Folder1 = "C:\Program Files\Cognos\TM1\bin\"
const tm1Folder2 = "C:\Program Files\GI TM1\bin\"
' At one point I had extra lines in for a Windows7 version that didn't work
const WindowsXP = "c:\windows\system32\mscomctl.ocx"

 
dim fso		' File System Object
dim tm1Dir
dim wincontrol
dim tm1Files
dim sCmd

set fso = createobject("Scripting.FileSystemObject")

' Check which folder the files are installed to - limited number of options unfortunately
' There is nothing in the IBM notes about having to re-register the TM1 Controls but on our PCs we found we had to do these on Win XP machines.
' On Windows 7 PCs we only had to do the mscomctl.ocx file.

if fso.fileexists (tm1folder1 & "tm1xl.ocx") then
	tm1dir = tm1folder1
	msg "Run Fix in : " & tm1folder1
end if

if fso.fileexists (tm1folder2 & "tm1xl.ocx") then
	tm1dir = tm1folder2
	msg "Run Fix in : " & tm1folder2
end if

if fso.fileexists (windowsxp) then
	wincontrol = windowsxp
end if

if tm1dir = "" or wincontrol = "" then
	msg "TM1 Files not found. Please contact ???"
else
	RunFixes
end if


sub RunFixes
dim sCMD
dim wShell
dim bReturnValue 

	set wshell = wscript.createobject ("WScript.Shell")
	
	scmd = "regsvr32 /s """ & tm1dir & "tm1xl.ocx"""
	breturnvalue =	wshell.run (scmd,1, true)
	if breturnvalue <> 0 then
		msg "Error Registering tm1xl.ocx. Please tell ???"
	end if
	
	scmd = "regsvr32 /s """ & tm1dir & "tm1prc.dll"""
	breturnvalue = wshell.run (scmd,1, true)
	if breturnvalue <> 0 then
		msg "Error Registering tm1prc.dll. Please tell ???"
	end if

	scmd = "regsvr32 /s """ & tm1dir & "tm1dasrv.dll"""
	breturnvalue = wshell.run (scmd,1, true)
	if breturnvalue <> 0 then
		msg "Error Registering tm1dasrv.dll. Please tell ???"
	end if
	
	
	scmd = "regsvr32 /u /s " & wincontrol
	breturnvalue = wshell.run (scmd,1, true)
	if breturnvalue <> 0 then
		msg "Error unregistering mscomctl.ocx. Please tell ???"
	end if
	
	scmd = "regsvr32 /s " & wincontrol
	breturnvalue = wshell.run (scmd,1, true)
	if breturnvalue <> 0 then
		msg "Error Registering mscomctl.ocx. Please tell ???"
	end if
	
	msgbox "Finished"
	
end sub


sub Msg (sText)
	msgbox stext
end sub