Get a list of element attributes in each dimension

[elee123]

Hi Everyone,
I need to get a list of all elements & its attributes in each dimension, and put them all in a table (Excel).
How can I do this?

lee

[tomok]

One by one, open the }ElementAttributes cube for each dimension, put the elements on rows and attributes on columns (or vice versa) and click on the snapshot icon.

[elee123]

There's gotta be a way to write a ti process to automate the whole procedure and store it in a cube, right?

[declanr]

There's gotta be a way to write a ti process to automate the whole procedure and store it in a cube, right?

If you only need it for 1 dimension then open the element attributes cube and do a slice, snapshot or active form. If you actually want it for every dimension then I'm sure that code similar to below will be in the forum somewhere if searching:

Code: Select all

DataSourceAsciiQuoteCharacter = '';
sDirectory = GetProcessErrorFileDirectory;
sDimDim = '}Dimensions';
iCount = 1;
iMax = DimSiz ( sDimDim );
While ( iCount <= iMax );
	sDimName = DimNm ( sDimDim, iCount );
	If ( SubSt ( sDimName, 1, 1 ) @<> '}' );
		sCubAttr = '}ElementAttributes_' | sDimName;
		sFileOutput = sDirectory | sDimName | '.txt';
		iColCount = 1;
		If ( CubeExists ( sCubAttr ) = 0 );
			iColMax = 0;
		Else;
			iColMax = DimSiz ( sCubAttr );
		EndIf;
		sHeader = 'Element';
		While ( iColCount <= iColMax );
			sHeader = sHeader | ',' | DimNm ( sCubAttr, iColCount );
			iColCount = iColCount + 1;
		End;
		AsciiOutput ( sFileOutput, sHeader );
		iElementCount = 1;
		iElementMax = DimSiz ( sDimName );
		While ( iElementCount <= iElementMax );
			sElementName = DimNm ( sDimName, iElementCount );
			sRowOutput = sElementName;
			iColCount = 1;
			While ( iColCount <= iColMax );
				sRowOutput = sRowOutput | ',' | CellGetS ( sCubAttr, sElementName, DimNm ( sCubAttr, iColCount ) );
				iColCount = iColCount + 1;
			End;
			AsciiOutput ( sFileOutput, sRowOutput );
			iElementCount = iElementCount + 1;
		End;
	EndIf;
	iCount = iCount + 1;
End;